entropical lukewarmity

identd

March 03rd 2006 Posted in Randomness

This is a tutorial for the novice Delphi programmer that understands the basics of socket communication. I wrote this because I, myself, am a novice Delphi programmer, and I’ve decided to chronicle my newfound knowledge as it comes.

The Identification Protocol, or IDENT, was originally used to identify which user on a machine owned a specific TCP/IP connection. It is, however, very easy to spoof, so there is no real security in using it. It is now only used in a few specific environments, such as IRC. Specifically, servers on networks such as EFNet require that your machine respond with an IDENT reply, or they will not allow you to connect. Most IRC clients have built-in servers to handle these requests, but some don’t. If you find yourself on Windows, with an IRC client that won’t do IDENT, then what you need is a lightweight EXE that runs in the background and responds to IDENT requests from IRC servers.

This IDENTd is not a full implementation, that would be beyond a novice tutorial. This is a simple program that takes an optional sUser parameter which it will then use to respond to any IDENT requests on port 113 (the standard IDENT port).

This code requires Aphex’s wonderful SocketUnit. It is an elegant wrapper for the Windows socket API that will be natural to use in an OOP environment like Delphi. Full responsibility for the elegance and simplicity of this code go to Aphex, he kicks ass.

To start, either download the RAR containing the binary and source from the bottom of the article, or, alternatively, open Delphi and select File > New > Other… and choose Console Application in the first tab. Once the project loads, you’ll want to delete all of the text that Delphi generates, and replace it with the code below, you’ll also have to Save As… and name it identd before it’ll let you compile.

USAGE:

identd
- optional username to respond with, otherwise “user” is used

SOURCE:

program identd;

{ Uncomment this line to see the console window, otherwise none is made. }
{ Note that any calls to WriteLn will generate an Exception unless it is specified. }
//{$APPTYPE CONSOLE}

{ SocketUnit in turn uses Winsock and Windows. }
{ Note that SysUtils, Classes, etc. are omitted. }
uses
  SocketUnit;

var
  Server: TServerSocket;                // the server variable
  Client: TClientSocket;                // the client for any incomming connections to the server
  bShutdown: Boolean;                   // when set to true, the server will stop listening for requests
  sUser, sReq, sRes: string;            // strings to hold the data

begin
  if ParamCount = 0 then                // if there are no command line parameters then
    sUser := 'user'                     // use the default setting
  else
    sUser := ParamStr(1);               // otherwise use the first command line parameter
  Server := TServerSocket.Create;       // create ServerSocket object
  bShutdown := false;                   // initialize boolean
  try
    Server.Listen(113);                 // specify 113 as the listening port, this is the standard IDENT port
    while not bShutdown do              // check shutdown flag
    begin
      Client := Server.Accept;          // create a new Client object with any incoming connections to Server
      try
        // technically, multiple IDENT requests can be made during a single connection
        while Client.Connected do
        begin
          // idle for up to 30 seconds waiting on data to come in on the socket
          Client.Idle(30);
          sReq := Client.ReceiveString; // store the request
          // if there was no request, then the connection is done, this jumps to the Finally clause
          if sReq = '' then
            Break;
          // this is the standard reply format for IDENT, simple, eh?
          sRes := sReq + ' : USERID : UNIX : ' + sUser;
          Client.SendString(sRes);      // send the string out to the socket
        end;
      finally
        Client.Destroy;                 // destroy the Client object, disconnecting first if necessary
      end;
    end;
  finally
    Server.Destroy;                     // destroy the Server object
  end;
end.

download source + exe